COMMENT ⊗   VALID 00002 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	BEGIN "PIXTS2"
C00007 ENDMK
C⊗;
BEGIN "PIXTS2"
REQUIRE "VIXNIC.SAI[VIS,HPM]" SOURCE_FILE;
REQUIRE "WIXNIC.SAI[VIS,HPM]" SOURCE_FILE;
INTEGER SIZE,W,CAMERA,CHN,WID,HIG,IAV;
BOOLEAN SYNA;
REQUIRE "⊂⊃<>" DELIMITERS;
DEFINE BOX(X1,Y1,X2,Y2)=
⊂	BEGIN
	LINE(X1,Y1,X2,Y1);
	LINE(X2,Y1,X2,Y2);
	LINE(X2,Y2,X1,Y2);
	LINE(X1,Y2,X1,Y1);
	END			⊃;
WID←HIG←256;
OUTSTR("CAMERA NUMBER:"); CAMERA←CVD(INCHWL) MOD 4;
OUTSTR("USE SYNTHESIZER?"); SYNA←(INCHWL LAND '137)="Y";
OUTSTR("SIZE= "&CVS(SIZE)&'15&'12);
   BEGIN
   INTEGER ARRAY P1[0:PIXDIM(WID,HIG,4)-1],
      P2[0:PIXDIM(WID%2,HIG%2,6)-1],
      P3[0:PIXDIM(WID%4,HIG%4,8)-1],
      P4[0:PIXDIM(WID%8,HIG%8,10)-1];
   INTEGER I,J;
   OUTSTR("READING ");
   MAKPIX(WID,HIG,4,P1[0]);
   CAMPIX(CAMERA,2,2,1,8,P1[0]);
   OUTSTR("DONE"&'15&'12);
   HAFPIC(P1[0],P2[0]);
   HAFPIC(P2[0],P3[0]);
   HAFPIC(P3[0],P4[0]);
   DDINIT; SCREEN(-1,-1,1,1);
   IF ¬SYNA THEN OUTSTR(CVOS(CHN←GDDCHN(-1))&" IS THE DD CHANNEL"&'15&'12);
   DRKEN; RECTAN(-1,-1,1,1); LITEN;
   FOR I←IF SYNA THEN 5 ELSE 0 STEP -1 UNTIL 0 DO
      BEGIN
      DRKEN; RECTAN(-1,-1,1,1);
      IF SYNA THEN VIDEO(-1,1,0,0,P1[0],2↑(I-2)) ELSE HAFTON(-1,1,0,0,P1[0]);
      IF SYNA THEN VIDEO(0,1,1,0,P2[0],2↑I) ELSE HAFTON(0,1,1,0,P2[0]);
      IF SYNA THEN VIDEO(-1,0,0,-1,P3[0],2↑(I+2)) ELSE HAFTON(-1,0,0,-1,P3[0]);
      IF SYNA THEN VIDEO(0,0,1,-1,P4[0],2↑(I+4)) ELSE HAFTON(0,0,1,-1,P4[0]);
      FOR J←1,2,3 DO DPYUP(IF SYNA THEN SYNMAP(I) ELSE CHN);
      IF ¬SYNA THEN SHOW(CHN);
      END;
   END;
OUTSTR("END OF RUN"&'15&'12);
END;